NeoTerm_System/build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    ext.getGitHeadRefsSuffix = {
        try {
            def headFile = new File('.git/HEAD')
            if (headFile.exists()) {
                String[] strings = headFile.getText('UTF-8').split(" ");
                if (strings.size() > 1) {
                    String refFilePath = '.git/' + strings[1];

                    def refFile = new File(refFilePath.replace("\n", ""));

                    return refFile.getText('UTF-8').substring(0, 7)
                }

            }
        } catch (Exception e) {
            e.printStackTrace()
        }
        return ""
    }

    ext.android = [
            ANDROID_SUPPORT_VERSION: '27.0.2',

            KOTLIN_VERSION         : '1.2.51',

            MIN_SDK_VERSION        : 21,

            COMPILE_SDK_VERSION    : 27,

            TARGET_SDK_VERSION     : 27,

            BUILD_TOOL_VERSION     : '28.0.3',

            JUNIT_VERSION          : "4.12"
    ]

    ext.deps = [
            "annotations"         : "com.android.support:support-annotations:${ext.android.ANDROID_SUPPORT_VERSION}",
            "appcompat-v7"        : "com.android.support:appcompat-v7:${ext.android.ANDROID_SUPPORT_VERSION}",
            "design"              : "com.android.support:design:${ext.android.ANDROID_SUPPORT_VERSION}",
            "cardview-v7"         : "com.android.support:cardview-v7:${ext.android.ANDROID_SUPPORT_VERSION}",
            "kotlin-stdlib"       : "org.jetbrains.kotlin:kotlin-stdlib-jre7:${ext.android.KOTLIN_VERSION}",
            "kotlin-gradle-plugin": "org.jetbrains.kotlin:kotlin-gradle-plugin:${ext.android.KOTLIN_VERSION}",
            "junit"               : "junit:junit:${ext.android.JUNIT_VERSION}"
    ]


    repositories {
        maven { url 'https://dl.google.com/dl/android/maven2/' }
        jcenter()
        google()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.2.1'
        classpath rootProject.ext.deps["kotlin-gradle-plugin"]

        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.2'
        classpath 'com.github.dcendents:android-maven-gradle-plugin:1.5'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        jcenter()
        maven { url 'https://dl.google.com/dl/android/maven2/' }
        mavenCentral()
        maven { url "https://jitpack.io" }
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}